Fazer referência à uma célula no excel [Resolvido/Fechado]

jonas trento buzzatti - 4 set 2013 às 10:47 - Última resposta: Mazzaropi 1834 Posts segunda 16 de agosto de 2010Data de inscriçãoContribuinteStatus 30 de maio de 2018 Última visita
- 5 set 2013 às 16:38
Bom dia,

numa série de valores (que não estão em ordem crescente ou decrescente quero fazer uma soma um subtração entre o valor mínimo (que pode variar dependendo do problema) e o seu valor na célula sequente (ou anterior) sem que precise especificar estas células.

Exemplo:
na sequencia 0,47 0,55 0,36 0,48 0,49 quero somar 0,36=0,55 ou 0,36+0,48

"=Mínimo(culunalinha:colunalinha)+ACÉLULA ANTERIOR OU POSTERIOR DESTE MÍNIMO"

Ver mais 

1 resposta

Melhor resposta
Mazzaropi 1834 Posts segunda 16 de agosto de 2010Data de inscriçãoContribuinteStatus 30 de maio de 2018 Última visita - 5 set 2013 às 16:38
1
Obrigado
Jonas Buzzatti, Bom Dia.

Vamos supor que a sua sequência esteja em A1 até E1

__---A---|---B---|---C---|---D---|---E---|
1 |.0,47.|.0,55..|.0,36..|.0,48.|.0,49..|

- Localizar o Valor Mínimo
Por exemplo, coloque em B4 a fórmula =Mínimo(A1:E1)
O resultado será 0,36

- Localizar a posição do Valor Mínimo na sequência
Já que temos a fórmula de como localizar o valor mínimo, vamos incluí-la na formula que localiza a posição deste valor na sequência.
Por exemplo, coloque em B5 a seguinte fórmula
=CORRESP(MÍNIMO(A1:E1);A1:E1;0)
O resultado será 3, ou seja, a terceira posição na sequência.

Como você precisa de somar o valor mínimo encontrado com o valor anterior a ele ou o valor posterior a ele na sequência, basta utilizar este posição MAIS um ou esta posição MENOS um para somar.

- Localizando o Valor ANTERIOR ao valor Mínimo na sequência
Por exemplo, coloque em B6 a fórmula
=ÍNDICE(A1:E1;;CORRESP(MÍNIMO(A1:E1);A1:E1;0)-1)
O resultado será 0,55

- Localizando o Valor POSTERIOR ao valor Mínimo na sequência
Por exemplo, coloque em B7 a fórmula
=ÍNDICE(A1:E1;;CORRESP(MÍNIMO(A1:E1);A1:E1;0)+1)
O resultado será 0,48

Agora que você sabe TODO o processo para achar os dados necessários, não é necessário utilizar todas estas células que foram usadas para demonstrar como funciona a fórmula final.

Basta fazer,
B7 -->
=(MÍNIMO(A1:E1))+(ÍNDICE(A1:E1;;CORRESP(MÍNIMO(A1:E1);A1:E1;0)-1))
O resultado será: Mínimo + ANTERIOR --> 0,36 + 0,55 = 0,91

B8 -->
=(MÍNIMO(A1:E1))+(ÍNDICE(A1:E1;;CORRESP(MÍNIMO(A1:E1);A1:E1;0)+1))
O resultado será: Mínimo + POSTERIOR --> 0,36 + 0,48 = 0,84


Era isto que você queria?

Espero ter ajudado.

Tenha um bom dia.

Obrigado, Mazzaropi 1

Algo a dizer? Adicionar comentário

CCM ajudou 9493 usuários este mês